view gaim2blt.pl @ 4946:154eb3188788

[gaim-migrate @ 5280] Another gaim first, ladies and gentlemen! I've been reading some books and sites on interface design and realized something. The natural order for humans (or at least Western people?) is a top-down approach. Menus drop down. Webpages go from top to bottom. You tend to scroll down rather than up. Everything goes from the top to the bottom. Apple realizes this, and that's why the menubar has always been at the top. Microsoft never really grasped this, and we all know how clunky the Start button feels. So this commit puts the input box on IMs (I'll get to chats after school) above the gtkimhtml widget. This feels much more natural, as what you type then jumps down to the input widget. Though it may look odd at first, you'll all realize just how comfortable gaim is now in comparison to any other IM client. committer: Tailor Script <[e-mail]>

#!/usr/bin/perl -w
# Original by Andy Harrison,
# Rewrite by Decklin Foster,
# Available under the GPL.

package Gaim2Blt;
use strict;
use Getopt::Std;
use vars qw(%opts $in_group);

getopts('s:', \%opts);
die "usage: $0 -s 'screen name' gaim.buddy\n" unless $opts{s};

print <<"EOF";
Config {
  version 1
}
User {
  screenname "$opts{s}"
}
Buddy {
  list {
EOF

while (<>) {
    chomp;
    my ($type, $args) = split ' ', $_, 2;
    next unless $type;

    if ($type eq 'g') {
        print "    }\n" if ($in_group);
        print qq(    "$args" {\n);
        $in_group = 1;
    } elsif ($type eq 'b') {
        my ($buddy, $alias) = split /:/, $args;
        print qq(      "$buddy"\n);
    }
}

print <<"EOF";
    }
  }
}
EOF