view m4/ac_var_timezone_externals.m4 @ 4089:7f4f3aa61069

[gaim-migrate @ 4304] Changing the button style in Preferences no longer reverts conversation windows to the old style. It should work now. Pictures, Text, and Pictures & Text all work for IMs and chats here. However, there may be bugs, so let me know. Note that the style you select is not applied to newly created windows during the same session or when gaim is restarted. This isn't my fault! :) This probably broke during either the preferences or conversations rewrite. committer: Tailor Script <[e-mail]>

# Define 'timezone', 'altzone' and 'daylight'
# http://www.gnu.org/software/ac-archive/Miscellaneous/ac_var_timezone_externals.html
# Use instead of 'AC_STRUCT_TIMEZONE' to determine whether the
# the external timezone variables 'timezone', 'altzone' and 'daylight' exist,
# defining 'HAVE_TIMEZONE', 'HAVE_ALTZONE' and 'HAVE_DAYLIGHT' respectively
# (as well as gaining the macros defined by 'AC_STRUCT_TIMEZONE').
# Mark R.Bannister <[e-mail]>
AC_DEFUN([AC_VAR_TIMEZONE_EXTERNALS],
[  AC_REQUIRE([AC_STRUCT_TIMEZONE])dnl
   AC_CACHE_CHECK(for timezone external, mb_cv_var_timezone,
   [  AC_TRY_LINK([#include <time.h>], [return (int)timezone;],
         mb_cv_var_timezone=yes,
         mb_cv_var_timezone=no)
   ])
   AC_CACHE_CHECK(for altzone external, mb_cv_var_altzone,
   [  AC_TRY_LINK([#include <time.h>], [return (int)altzone;],
         mb_cv_var_altzone=yes,
         mb_cv_var_altzone=no)
   ])
   AC_CACHE_CHECK(for daylight external, mb_cv_var_daylight,
   [  AC_TRY_LINK([#include <time.h>], [return (int)daylight;],
         mb_cv_var_daylight=yes,
         mb_cv_var_daylight=no)
   ])
   if test $mb_cv_var_timezone = yes; then
      AC_DEFINE([HAVE_TIMEZONE], 1,
              [Define if you have the external 'timezone' variable.])
   fi
   if test $mb_cv_var_altzone = yes; then
      AC_DEFINE([HAVE_ALTZONE], 1,
              [Define if you have the external 'altzone' variable.])
   fi
   if test $mb_cv_var_daylight = yes; then
      AC_DEFINE([HAVE_DAYLIGHT], 1,
              [Define if you have the external 'daylight' variable.])
   fi
])