annotate lisp/cedet/srecode/srt.el @ 105652:51bc239bdc37

* cedet/srecode/srt.el: * cedet/srecode/compile.el: * cedet/semantic/mru-bookmark.el: * cedet/semantic/debug.el: * cedet/semantic/complete.el: * cedet/semantic/analyze.el: Require CL when compiling. * cedet/semantic/scope.el (semantic-analyze-scoped-inherited-tag-map): Wrap calculation of tmpscope so that the regular scope will continue to work. * cedet/semantic/idle.el (semantic-idle-tag-highlight): Use semantic-idle-summary-highlight-face as the highlighting. * emacs-lisp/eieio-base.el (eieio-persistent-save): If buffer contains multibyte characters, choose first applicable coding system automatically. * cedet/ede/project-am.el (project-run-target): New method. (project-run-target): New method. * cedet/ede.el (ede-target): Add run target menu item. (ede-project, ede-minor-keymap): Add ede-run-target binding. (ede-run-target): New function. (ede-target::project-run-target): New method. * cedet/ede/proj.el (project-run-target): New method. * cedet/ede/proj-shared.el (ede-gcc-libtool-shared-compiler) (ede-g++-libtool-shared-compiler): Remove SHELL. Remove COMMANDS. Add :rules. (ede-proj-target-makefile-shared-object): Only libtool compilers now available. Add linkers for libtool. (ede-cc-linker-libtool, ede-g++-linker-libtool): New. (ede-proj-makefile-target-name): Always use .la extension. * cedet/ede/proj-prog.el (project-run-target): New method. * cedet/ede/proj-obj.el (ede-cc-linker): Rename from ede-gcc-linker. (ede-g++-linker): Change Change link lines. * cedet/ede/pmake.el (ede-pmake-insert-variable-shared): When searching for old variables, go to the end of the buffer and search backward from there. (ede-proj-makefile-automake-insert-subdirs) (ede-proj-makefile-automake-insert-extradist): New methods. (ede-proj-makefile-create): Use them. * cedet/ede/pconf.el (ede-proj-configure-test-required-file): Force FILE to expand to the current target. Use file-exists-p to check that it exists. * cedet/ede/linux.el (ede-linux-version): Don't call "head". (ede-linux-load): Wrap dir in file-name-as-directory. Set :version slot. * cedet/ede/files.el (ede-get-locator-object): When enabling locate, do so on "top". * cedet/ede/emacs.el (ede-emacs-file-existing): Wrap "dir" in file-name-as-directory during compare. (ede-emacs-version): Return Emacs/XEmacs differentiator. Get version number from different places. Don't call egrep. (ede-emacs-load): Set :version slot. Call file-name-as-directory to set the directory. * cedet/ede/shell.el: New file. * cedet/inversion.el (inversion-decoders): Allow for stray . in alpha/beta variants.

;;; srecode/srt.el --- argument handlers for SRT files

;; Copyright (C) 2008, 2009 Free Software Foundation, Inc.

;; Author: Eric M. Ludlam <[e-mail]>

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:
;;
;; Filters for SRT files, the Semantic Recoder template files.

;;; Code:

(eval-when-compile (require 'cl))
(require 'eieio)
(require 'srecode/dictionary)
(require 'srecode/insert)

(defvar srecode-read-variable-name-history nil
  "History for `srecode-read-variable-name'.")

(defun srecode-read-variable-name (prompt &optional initial hist default)
  "Read in the name of a declared variable in the current SRT file.
PROMPT is the prompt to use.
INITIAL is the initial string.
HIST is the history value, otherwise `srecode-read-variable-name-history'
     is used.
DEFAULT is the default if RET is hit."
  (let* ((newdict (srecode-create-dictionary))
	 (currfcn (semantic-current-tag))
	 )
    (srecode-resolve-argument-list
     (mapcar 'read
	     (semantic-tag-get-attribute currfcn :arguments))
     newdict)

    (with-slots (namehash) newdict
      (completing-read prompt namehash nil nil initial
		       (or hist 'srecode-read-variable-name-history)
		       default))
    ))

(defvar srecode-read-major-mode-history nil
  "History for `srecode-read-variable-name'.")

(defun srecode-read-major-mode-name (prompt &optional initial hist default)
  "Read in the name of a desired `major-mode'.
PROMPT is the prompt to use.
INITIAL is the initial string.
HIST is the history value, otherwise `srecode-read-variable-name-history'
     is used.
DEFAULT is the default if RET is hit."
  (completing-read prompt obarray
		   (lambda (s) (string-match "-mode$" (symbol-name s)))
		   nil initial (or hist 'srecode-read-major-mode-history))
  )

(defun srecode-semantic-handle-:srt (dict)
  "Add macros into the dictionary DICT based on the current SRT file.
Adds the following:
ESCAPE_START - This files value of escape_start
ESCAPE_END - This files value of escape_end
MODE - The mode of this buffer.  If not declared yet, guess."
  (let* ((es (semantic-find-first-tag-by-name "escape_start" (current-buffer)))
	 (ee (semantic-find-first-tag-by-name "escape_end" (current-buffer)))
	 (mode-var (semantic-find-first-tag-by-name "mode" (current-buffer)))
	 (mode (if mode-var
		   (semantic-tag-variable-default mode-var)
		 nil))
	 )
    (srecode-dictionary-set-value dict "ESCAPE_START"
				  (if es
				      (car (semantic-tag-variable-default es))
				    "{{"))
    (srecode-dictionary-set-value dict "ESCAPE_END"
				  (if ee
				      (car (semantic-tag-variable-default ee))
				    "}}"))
    (when (not mode)
      (let* ((fname (file-name-nondirectory
		     (buffer-file-name (current-buffer))))
	     )
	(when (string-match "-\\(\\w+\\)\\.srt" fname)
	  (setq mode (concat (match-string 1 fname) "-mode")))))

    (when mode
      (srecode-dictionary-set-value dict "MAJORMODE" mode))

    ))

(provide 'srecode/srt)

;; arch-tag: fb69da04-0bd6-48fe-b935-f8668420ecaf
;;; srecode/srt.el ends here