view m4/ac_var_timezone_externals.m4 @ 4109:4efc492cf16f

[gaim-migrate @ 4324] (21:14:00) Robot101: although I just had a thought.... before you commit it, change this: (21:14:11) LSchiere: ugh (21:14:24) Robot101: trust me, it's far harder for me to re-diff it :P (21:14:30) LSchiere: not now it isn't (21:14:34) LSchiere: what line? (21:14:53) LSchiere: of the file not the patch (21:15:05) Robot101: buddy.c 2479 (21:15:22) LSchiere: kay (21:15:36) LSchiere: gint x, y, width, height; (21:15:47) Robot101: remove width and height, then remove the call to gtk_window_get_size, and change the 4 occurences of width and height to event.width and event.height (21:16:13) Robot101: size is not dependent on gravity, so we don't need to get it via gtk. (21:17:03) LSchiere: any other thoughts? (21:17:33) Robot101: yes. I'm an idiot. (21:17:42) LSchiere: you said it, not me. (21:17:53) deryni: I smell commit message committer: Tailor Script <[e-mail]>

# Define 'timezone', 'altzone' and 'daylight'
# http://www.gnu.org/software/ac-archive/Miscellaneous/ac_var_timezone_externals.html
# Use instead of 'AC_STRUCT_TIMEZONE' to determine whether the
# the external timezone variables 'timezone', 'altzone' and 'daylight' exist,
# defining 'HAVE_TIMEZONE', 'HAVE_ALTZONE' and 'HAVE_DAYLIGHT' respectively
# (as well as gaining the macros defined by 'AC_STRUCT_TIMEZONE').
# Mark R.Bannister <[e-mail]>
AC_DEFUN([AC_VAR_TIMEZONE_EXTERNALS],
[  AC_REQUIRE([AC_STRUCT_TIMEZONE])dnl
   AC_CACHE_CHECK(for timezone external, mb_cv_var_timezone,
   [  AC_TRY_LINK([#include <time.h>], [return (int)timezone;],
         mb_cv_var_timezone=yes,
         mb_cv_var_timezone=no)
   ])
   AC_CACHE_CHECK(for altzone external, mb_cv_var_altzone,
   [  AC_TRY_LINK([#include <time.h>], [return (int)altzone;],
         mb_cv_var_altzone=yes,
         mb_cv_var_altzone=no)
   ])
   AC_CACHE_CHECK(for daylight external, mb_cv_var_daylight,
   [  AC_TRY_LINK([#include <time.h>], [return (int)daylight;],
         mb_cv_var_daylight=yes,
         mb_cv_var_daylight=no)
   ])
   if test $mb_cv_var_timezone = yes; then
      AC_DEFINE([HAVE_TIMEZONE], 1,
              [Define if you have the external 'timezone' variable.])
   fi
   if test $mb_cv_var_altzone = yes; then
      AC_DEFINE([HAVE_ALTZONE], 1,
              [Define if you have the external 'altzone' variable.])
   fi
   if test $mb_cv_var_daylight = yes; then
      AC_DEFINE([HAVE_DAYLIGHT], 1,
              [Define if you have the external 'daylight' variable.])
   fi
])